Mid(stringvar, start[, length]) = string - заменяет символы в строке stringvar начиная с позиции start символами, содержащимися в строке string.

Пример:

Dim MyString
MyString = "The dog jumps" ' Инициализируем строку
Mid(MyString, 5, 3) = "fox" ' MyString = "The fox jumps".
Mid(MyString, 5) = "cow" ' MyString = "The cow jumps".
Mid(MyString, 5) = "cow jumped over" ' MyString = "The cow jumpe".
Mid(MyString, 5, 3) = "duck" ' MyString = "The duc jumpe".

MkDir path - создаёт каталог path.

Пример:

MkDir "MYDIR" ' Создаёт новую папку в текущем каталоге.
MkDir "C:\MYDIR" ' Создаёт новую папку в корневом каталоге диска С.

N

Name oldpathname As newpathname - переименовывает файл или каталог с именем oldpathname в файл или каталог с именем newpathname.

Пример:

Dim OldName, NewName
OldName = "OLDFILE": NewName = "NEWFILE" ' Устанавливаем имена
Name OldName As NewName ' Переименовываем

OldName = "C:\MYDIR\OLDFILE": NewName = "C:\YOURDIR\NEWFILE"
Name OldName As NewName ' Перемещаем и переименовываем файл

O

On Error GoTo line
On Error Resume Next
On Error GoTo 0

Устанавливает обработчик ошибок на процедуру. Первый оператор указывает метку, на которую будет передано управление при возникновении ошибки. С помощью второго оператора можно сделать так, чтобы при возникновении ошибки программа продолжала работать. И, наконец, третий позволяет отключить все ранее установленные обработчики ошибок.

Пример:

Dim strVar As String
' Устанавливаем обработчик ошибки
On Error GoTo OSHIBKA
'Открываем несуществующий файл.Возникает ошибка №53 "Файл не найден" и
' программа передаёт управление на метку OSHIBKA
Open "C:\Windows\MyIni.ini" For Input As #3
Input #3, strVar
Close #3
Exit Sub ' Нужно выйти из процедуры, иначе появится ненужный MsgBox

OSHIBKA:
If Err.Number = 53 Then ' Объект Err - содержит свойства ошибки
MsgBox "Файл не найден!", vbCritical, "error"
Else
MsgBox "Какая-то другая ошибка!", vbCritical, "error"
End If

Open pathname For mode [Access access] [lock] As [#]filenumber [Len=reclength] - открывает файл для чтения, записи или для произвольного доступа.

Пример:

' Открываем файл для последовательного чтения
Open "TESTFILE" For Input As #1
' Закрываем файл перед тем, как открыть его снова другим методом
Close #1

' Открываем для двоичного доступа и только для записи
Open "TESTFILE" For Binary Access Write As #1
' Закрываем файл перед тем, как открыть его снова другим методом
Close #1

' Этот пример открывает файл для произвольного доступа.
' Файл содержит записи определённого пользователем типа.

Type Record
ID As Integer
Name As String * 20
End Type

Dim MyRecord As Record ' Объявляем переменную типа запись
Open "TESTFILE" For Random As #1 Len = Len(MyRecord)
' Закрываем файл перед тем, как открыть его снова другим методом
Close #1

' Открываем файл для последовательной записи.
' Причём другие процессы также могут записывать или читать этот файл.

Open "TESTFILE" For Output Shared As #1
' Закрываем файл перед тем, как открыть его снова другим методом
Close #1

'Этот оператор открывает файл для двоичного доступа только для чтения,
' Причём другие процессы не могут обращаться к этому файлу!

Open "TESTFILE" For Binary Access Read Lock Read As #1

Option Base {0 | 1} - задаёт нижний предел для массивов. Оператор действует на уровне модуля. По умолчанию все массивы начинают свои индексы с нуля.

Пример:

Option Base 1 ' Устанавливаем границу для массивов равной единице

Dim Lower
Dim MyArray(20), TwoDArray(3, 4) ' Объявляем массивы
Dim ZeroArray(0 To 5) ' Этот массив всё равно начнётся с нуля
' Используем ф-цию LBound для выявления нижней границы массива
Lower = LBound(MyArray) ' Возвратит 1.
Lower = LBound(TwoDArray, 2) ' Возвратит 1.
Lower = LBound(ZeroArray) ' Возвратит 0.

Option Compare {Binary | Text | Database} - То же, что и выше, только задаёт тип сравнения, который будет использоваться по умолчанию. По умолчанию используется бинарный тип сравнения.

Пример:

' Устанавливаем бинарный тип сравнения.
Option Compare Binary ' Теперь, строка "AAA" меньше, чем "aaa".
' Устанавливаем текстовый тип сравнения.
Option Compare Text ' Теперь, строка "AAA" равна строке "aaa".

Option Explicit - Если задать этот оператор, то нельзя будет использовать необъявленные ранее переменные, например, как в паскале.

Пример:

Option Explicit
Dim MyVar ' Объявляем переменную
MyInt = 10
' MyInt - необъявленная переменная, поэтому произойдёт ошибка
MyVar = 10 ' Здесь всё ОК

Option Private Module - делает модуль приватным. Т.е. его методы и функции не могут быть использованы в других подключённых проектах.

Пример:

Option Private Module ' Теперь модуль Module - приватный